Neuron methodsFor: 'accessing evaluation'
!
activationFunction
    "出力値を整形する活性化関数を提供する。
    今回は論理値を返せれば良いので出力が0以下なら0、1以上なら1を返す。"

	^ [ :value | ( 0 < value ) asInteger ].
!!

Neuron methodsFor: 'evaluation'
!
thought: aInputValuesCollection
    "学習結果に基づき、入力値から出力値を出す思考関数。
    パーセプトロンの本体といえる。
    
    入力値としては下記の形式の値を期待する。(末尾以外は任意の値で末尾は必ず1)
    #( 0 0 1 )
    #( 0 1 1 )
    末尾の値である1は閾値を表す。
    "
    
	"入力値の制限。入力値の数は重みの数と一致している必要がある。"
	self size = aInputValuesCollection size
		ifFalse:
		[
			self
				error: 'Should aInputValuesCollection size to equal self size'
		].

    "パーセプトロンの最重要部。入力値と重みをそれぞれ掛け合わせ、
    その合計から出力値を出す。( selfは重みの配列 )"
	^ self activationFunction
		value:	( aInputValuesCollection * self ) sumNumbers.
!!

Neuron methodsFor: 'accessing learning'
!
errorFunction
    "誤った値を正解の値に近づけるための誤差関数を提供する。
    正確には誤差関数そのものではないが、誤差関数は偏微分により
    誤差関数を構成する式の半分が消失するためここでは下記を誤差関数として扱う"
    
	^
	[ :outputValueCollection :expectedNumber |
		expectedNumber - outputValueCollection.
	]
!!

Neuron methodsFor: 'learning'
!
learnFrom:	aInputValueCollection
to:			aExpectedNumber        "期待値・正解値"
    "1通り分の学習関数。
    #( 1 1 1 )であれば1であるべきという値を受け取り、
    そうなっていなければ重みを正解に近づくよう調整する。"

	| result |
	
	result :=
		self
			thought: aInputValueCollection.

	^
	{
		"上記の実行結果を正解の値に近づける。( selfは重みの配列 )
		調整後の重みを戻り値として返す。"
		self +
		(
			(
				self errorFunction
					value: 	result
					value:	aExpectedNumber
			"0.001は精度と学習速度を調整する値で、
			それらを鑑みてちょうど良い値を指定する。"
			) * aInputValueCollection * 0.001
		).
		"後で使えるように、実行結果も返す。"
		result
	}.
!
learnAll:	aExpectedWithInputValuesCollection
    "全通り分の学習関数。
    例えば論理積であれば下記をすべて満たす必要があるが、
    1通り分の学習関数では、下記のうちどれか1つを満たす
    パーセプトロンしか作ることができない。
    この関数では下記すべてを満たすパーセプトロンを作る。
    
    #( 0 0 1 )であれば0。
    #( 0 1 1 )であれば0。
    #( 1 0 1 )であれば0。
    #( 1 1 1 )であれば1。
    
    入力値としては下記の形式の値を期待する。(末尾以外は任意の値で末尾は必ず1)
    一番左の値は正解値となる。
    #(
        ( 0 ( 0 0 1 ) )
        ( 1 ( 1 1 1 ) )
    )"
	| weight |

	weights := self.
	"全ての条件が正解になるまで学習を繰り返す。"
	[
		(
			aExpectedWithInputValuesCollection
				collect: 
				[ :each |
					| tuple |

					tuple :=
						weights
							learnFrom: 	each last
							to: 		each first.

					weights := tuple first.
					"実行結果が正解になっているか確認する。"
					each first = tuple last.
				]
		)
    		"不正解が残っているか確認し、残っていればもう一度学習させる。"
			includes:	false.
	] whileTrue.

	^ weights.
!!

| and |

and :=
	Neuron
		new: 	3.

"論理積を学習させる。"
and :=
	and
		learnAll:
		#(
			( 0 ( 0 0 1 ) )
			( 0 ( 0 1 1 ) )
			( 0 ( 1 0 1 ) )
			( 1 ( 1 1 1 ) )
		).

"論理積回路として動作する。"
and
	thought: #( 0 1 1 ). "→ 0"
and
	thought: #( 1 1 1 ). "→ 1"